用 ESP8266 做自動隨會議開關的OnAir燈箱

簡介

最近公司想要做一個裝置，是當 google 行事曆有排會議時，就會自動ON AIR的燈箱。

大概的思考架構

由 google apps script 生成三天內行事曆的JSON網站。
接著由 ESP8266 去網站上面抓網頁的資訊。
ESP8266 判斷時間是否在會議的開始與結束時間，如果在這個區段內的話，進行亮燈、否則暗燈。

所需材料與架構

esp8266
大創買的收納盒

去文具行買玻璃紙與黑紙卡
影印店印ON AIR字卡
5V 燈條

注意事項

燈條買SMD(直接焊在電路板的那種)，有嘗試使用大創賣的聖誕燈條，但是效果很醜。
玻璃紙與黑紙卡可以發揮自己創意改裝。

Google Apps Script 設定

首先進入google apps script

開一個新的檔案，將程式碼複製上去。

function doGet(e) {
  var calendarId = 'primary'; // Replace with your calendar ID
  var now = new Date();
  var nextWeek = new Date();
  nextWeek.setDate(nextWeek.getDate() + 4);

  var events = CalendarApp.getCalendarById(calendarId).getEvents(now, nextWeek);
  var output = events.map(function(event) {
    return {
      'title': event.getTitle(),
      'start': Math.floor(event.getStartTime().getTime() / 1000), // Convert to Unix timestamp
      'end': Math.floor(event.getEndTime().getTime() / 1000) // Convert to Unix timestamp
    };
  });

  return ContentService.createTextOutput(JSON.stringify(output))
    .setMimeType(ContentService.MimeType.JSON);
}

calendarId可以換成你想要的日曆ID。
ID的位置在日曆的旁邊會看到三個點點，點進去設定。

往下滑即可找到日曆ID

部屬網站

按上面的【執行】，這時候可能會跳行事曆的授權，按確認即可。(如果沒有跑出來，可以再按一次執行)
接著按右上角的【部屬】>【新增部屬工具】
按左上角的齒輪>【網頁應用程式】
執行身分 [我]
誰可以存取 [所有人]
即可完成部屬

紀錄ID及網站

(如果不見可以從【部屬】>【管理部屬工具】找)

接著會看到部屬ID跟網址，請將部屬ID記錄好。
網址可以測試看看是否可以順利看到JSON檔案
記得如果有跟改任何參數記得重新佈署一次

網址點進去應該會看到這樣：

note：本程式為了之後容易計算，因此時間是使用UNIX時間來表示

到目前已經完成網站端的配置了，接下來要來進行ESP32的部分。

ESP8266 設定

ESP8266硬體安裝

這次使用的是ESP8266上的D0腳位，將燈條的正極接在D0，負極接在GND上。

將程式貼進IDE

#include <ESP8266WiFi.h>
#include <ESP8266HTTPClient.h>
#include <WiFiClientSecureBearSSL.h>
#include <ArduinoJson.h>

//wifi帳號密碼
const char* ssid = "***";
const char* password = "***";

//Script ID.
const char *GScriptId = "***";

String resource = "/macros/s/" + String(GScriptId) + "/exec";
const char* host = "https://script.google.com";
const long timezoneOffset = 8 * 60 * 60;
const int ledPin = D0;

void setup() {
  Serial.begin(115200);
  pinMode(ledPin, OUTPUT);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
  }
  configTime(timezoneOffset, 0, "pool.ntp.org");
}

void loop() {
  if (WiFi.status() == WL_CONNECTED) {
    std::unique_ptr<BearSSL::WiFiClientSecure> client(new BearSSL::WiFiClientSecure);
    client->setInsecure();
    HTTPClient http;
    http.setFollowRedirects(HTTPC_STRICT_FOLLOW_REDIRECTS);
    http.begin(*client, host + resource);
    int httpCode = http.GET();

    if (httpCode > 0) {
      String payload = http.getString();
      Serial.println(httpCode);
      Serial.println(payload);

      DynamicJsonDocument doc(1024);
      deserializeJson(doc, payload);

      time_t now;
      time(&now);
      int nearestIndex = -1;
      time_t nearestDiff = INT_MAX;
      for (int i = 0; i < doc.size(); i++) {
        time_t start = doc[i]["start"].as<long>() + timezoneOffset;
        time_t diff = abs(now - start);
        if (diff < nearestDiff) {
          nearestIndex = i;
          nearestDiff = diff;
        }
      }

      if (nearestIndex != -1) {
        time_t start = doc[nearestIndex]["start"].as<long>();
        time_t end = doc[nearestIndex]["end"].as<long>();

        if (now >= start && now <= end) {
          digitalWrite(ledPin, HIGH);
          Serial.println("燈泡情況：ON");
        } else {
          digitalWrite(ledPin, LOW);
          Serial.println("燈泡情況：OFF");
        }
      }

      payload = "";
    }

    http.end();
  }
  
  delay(30000);
  //30秒抓一次資料
}